(*Potencial en el plano xy con 0≤x≤L y condiciones de contorno ϕ(x=0,y)=Sign[y]V y ϕ(x=L,y)=0 *)
(*Función de Green. Sin pérdida de generalidad tomamos L=1 (la recuperamos al final para obtener unidades de longitud).
Meto el signo menos del potencial del problema 6 adentro del logaritmo invirtiendo su argumento.*)
G[x_,xp_,y_,yp_]:=Log[((Cos[π(x+xp)]-Cosh[π(y-yp)])/(Cos[π(x-xp)]-Cosh[π(y-yp)]))];

(*Derivo respecto de -xp, la dirección normal que apunta hacia afuera del volumen*)
-Simplify[D[G[x,xp,y,yp],xp]]

Gn[x_,xp_,y_,yp_]:=((-2 π Sin[π x] (Cos[π x]-Cos[π xp] Cosh[π y] Cosh[π yp]+Cos[π xp] Sinh[π y] Sinh[π yp]))/((Cos[π (x-xp)]-Cosh[π (y-yp)]) (-Cos[π (x+xp)]+Cosh[π (y-yp)])))

(*Evalúo en xp=0*)
Simplify[Gn[x,0,y,yp]]

(*Multiplico por el ((-1)/(4π)) de la identidad de Green para el problema de Dirichlet, y por V, e integro respecto de yp. a=Cos[π x]*)

((2 π V)/(-4π))*Sin[π x]*Assuming[-1≤ a≤ 1&&y∈Reals,Integrate[(1/(a-Cosh[π (y-yp)])),yp]]

(*(Sqrt[1-(a^2)]) no es más que el Sin[π x] (que es positivo para x entre 0 y 1). 
Ahora hay que evaluar el resultado anterior entre 0 y ∞ con signo positivo y entre -∞ y 0 con signo negativo.*)

f[yp_]=((-V)/π) ArcTan[(((1+Cos[π x]) Tanh[(1/2) π (y-yp)])/(Sin[π x]))] ;
g[yp_]=f[-yp];
Assuming[0<=x<=1&&x∈Reals&&y∈Reals,Simplify[f[∞]-2*f[0]+g[∞]]]

(*Grafico el resultado para V=1.*)
Plot3D[((2 ArcTan[Cot[((π x)/2)] Tanh[((π y)/2)]])/π),{x,0,1},{y,-1,1},ImageSize->500,AxesLabel->{"x","y","ϕ"}]

(*Compruebo que el laplaciano sea nulo*)
Simplify[Laplacian[((2 ArcTan[Cot[((π x)/2)] Tanh[((π y)/2)]])/π),{x,y}]]

(*Reescribo el resultado final, reintroduciendo V y L*)
ϕ(x,y)=((2 V ArcTan[Cot[((π x)/(2 L))] Tanh[((π y)/(2 L))]])/π)